x86_64: position-independent kernel

2025-07-17 16:45:57 +03:00
parent 019146e9ff
commit 511d1e45c0
16 changed files with 578 additions and 650 deletions
@@ -1,52 +0,0 @@
-ENTRY(__x86_64_entry);
-
-KERNEL_PHYS_BASE = 0x200000;
-KERNEL_VIRT_OFFSET = 0xFFFFFF8000000000;
-
-SECTIONS {
-    . = KERNEL_PHYS_BASE;
-    PROVIDE(__kernel_start = . + KERNEL_VIRT_OFFSET);
-
-    .text.entry : {
-        *(.text.entry)
-    }
-
-    . = ALIGN(16);
-    . = . + KERNEL_VIRT_OFFSET;
-
-    .text : AT(. - KERNEL_VIRT_OFFSET) {
-        *(.text*)
-    }
-
-    .export.text : AT(. - KERNEL_VIRT_OFFSET) {
-        KEEP(*(.export.text*))
-    }
-
-    . = ALIGN(4K);
-    .rodata : AT(. - KERNEL_VIRT_OFFSET) {
-        *(.eh_frame*)
-        *(.rodata*)
-    }
-
-    . = ALIGN(4K);
-    .data.tables : AT (. - KERNEL_VIRT_OFFSET) {
-        KEEP(*(.data.tables))
-    }
-
-    .data : AT(. - KERNEL_VIRT_OFFSET) {
-        KEEP(*(.data.yboot))
-        *(.data*)
-        *(.got*)
-    }
-
-    . = ALIGN(4K);
-    PROVIDE(__bss_start_phys = . - KERNEL_VIRT_OFFSET);
-    .bss : AT(. - KERNEL_VIRT_OFFSET) {
-        *(COMMON)
-        *(.bss*)
-    }
-    . = ALIGN(4K);
-    PROVIDE(__bss_end_phys = . - KERNEL_VIRT_OFFSET);
-
-    PROVIDE(__kernel_end = .);
-};
@@ -0,0 +1,73 @@
+ENTRY(__x86_64_entry);
+
+SECTIONS {
+    . = 0x0;
+
+    PROVIDE(__kernel_start = .);
+
+    .text : {
+        *(.text.entry)
+        *(.text*)
+    }
+
+    . = ALIGN(4K);
+
+    .rodata : {
+        *(.rodata*)
+        *(.eh_frame*)
+
+        . = ALIGN(16);
+        PROVIDE(__init_array_start = .);
+        KEEP(*(.init_array*));
+        PROVIDE(__init_array_end = .);
+    }
+
+    . = ALIGN(4K);
+
+    .rela : {
+        PROVIDE(__rela_start = .);
+        *(.rela*)
+        PROVIDE(__rela_end = .);
+    }
+
+    .dynamic : {
+        *(.dynamic)
+    }
+
+    . = ALIGN(4K);
+
+    .data : {
+        KEEP(*(.data.yboot))
+        *(.data*)
+        *(.got*)
+    }
+
+    . = ALIGN(4K);
+    PROVIDE(__bss_start = .);
+
+    .bss : {
+        *(COMMON)
+        *(.bss*)
+    }
+
+    . = ALIGN(4K);
+    PROVIDE(__bss_end = .);
+    PROVIDE(__kernel_end = .);
+    PROVIDE(__kernel_size = __kernel_end - __kernel_start);
+
+    .dynsym : {
+        *(.dynsym)
+    }
+
+    .gnu.hash : {
+        *(.gnu.hash)
+    }
+
+    .hash : {
+        *(.hash)
+    }
+
+    .dynstr : {
+        *(.dynstr)
+    }
+}
@@ -15,6 +15,7 @@
  "panic-strategy": "abort",
  "dynamic-linking": true,
  "relocation-model": "pic",
+  "position-independent-executables": true,

  "has-thread-local": false,