aarch64: add raspberry pi 4b target

etc/aarch64-unknown-raspi4b.json

@@ -0,0 +1,20 @@
+{
+  "is-builtin": false,
+  "arch": "aarch64",
+  "os": "none",
+  "llvm-target": "aarch64-unknown-none",
+  "data-layout": "e-m:e-i8:8:32-i16:16:32-i64:64-i128:128-n32:64-S128-Fn32",
+  "max-atomic-width": 128,
+  "target-pointer-width": "64",
+  "features": "+v8a,+strict-align,-neon,-fp-armv8",
+
+  "disable-redzone": true,
+  "executables": true,
+  "panic-strategy": "abort",
+  "dynamic-linking": true,
+  "relocation-model": "pic",
+  "eh-frame-header": false,
+
+  "linker": "rust-lld",
+  "linker-flavor": "ld.lld"
+}

etc/ld/arm/aarch64-unknown-qemu.ld

@@ -21,12 +21,13 @@ SECTIONS {
 
     . = ALIGN(4K);
     .rodata : AT(. - KERNEL_VIRT_OFFSET) {
-        *(.eh_frame*)
-        . = ALIGN(16);
-        PROVIDE(__dt_probes_start = .);
-        KEEP(*(.dt_probes));
-        PROVIDE(__dt_probes_end = .);
         *(.rodata*)
+        *(.eh_frame*)
+
+        . = ALIGN(16);
+        PROVIDE(__init_array_start = .);
+        KEEP(*(.init_array*))
+        PROVIDE(__init_array_end = .);
     }
 
     . = ALIGN(4K);
@@ -48,6 +49,7 @@ SECTIONS {
     }
     . = ALIGN(4K);
     PROVIDE(__bss_end_phys = . - KERNEL_VIRT_OFFSET);
+    PROVIDE(__bss_size = __bss_end_phys - __bss_start_phys);
 
     PROVIDE(__kernel_end = .);
 };

etc/ld/arm/aarch64-unknown-raspi4b.ld

@@ -0,0 +1,55 @@
+ENTRY(__aarch64_entry);
+
+KERNEL_PHYS_BASE = 0x80000;
+KERNEL_VIRT_OFFSET = 0xFFFFFF8000000000;
+
+SECTIONS {
+    . = KERNEL_PHYS_BASE;
+    PROVIDE(__kernel_start = . + KERNEL_VIRT_OFFSET);
+
+    .text.entry : {
+        *(.text.entry)
+    }
+
+    . = ALIGN(16);
+    . = . + KERNEL_VIRT_OFFSET;
+
+    .text : AT(. - KERNEL_VIRT_OFFSET) {
+        KEEP(*(.text.vectors));
+        *(.text*)
+    }
+
+    . = ALIGN(4K);
+    .rodata : AT(. - KERNEL_VIRT_OFFSET) {
+        *(.rodata*)
+        *(.eh_frame*)
+
+        . = ALIGN(16);
+        PROVIDE(__init_array_start = .);
+        KEEP(*(.init_array*))
+        PROVIDE(__init_array_end = .);
+    }
+
+    . = ALIGN(4K);
+    .data.tables : AT (. - KERNEL_VIRT_OFFSET) {
+        KEEP(*(.data.tables))
+    }
+
+    . = ALIGN(4K);
+    .data : AT(. - KERNEL_VIRT_OFFSET) {
+        *(.data*)
+        *(.got*)
+    }
+
+    . = ALIGN(4K);
+    PROVIDE(__bss_start_phys = . - KERNEL_VIRT_OFFSET);
+    .bss : AT(. - KERNEL_VIRT_OFFSET) {
+        *(COMMON)
+        *(.bss*)
+    }
+    . = ALIGN(4K);
+    PROVIDE(__bss_end_phys = . - KERNEL_VIRT_OFFSET);
+    PROVIDE(__bss_size = __bss_end_phys - __bss_start_phys);
+
+    PROVIDE(__kernel_end = .);
+};