rv64: boot into upper half

2025-01-17 02:25:49 +02:00
parent 07458f33e4
commit 86eb2d3252
36 changed files with 1262 additions and 20 deletions
@@ -0,0 +1,57 @@
+ENTRY(__rv64_entry);
+
+KERNEL_PHYS_BASE = 0x80000000;
+KERNEL_VIRT_OFFSET = 0xFFFFFFF000000000;
+
+SECTIONS {
+    . = KERNEL_PHYS_BASE;
+    PROVIDE(__kernel_start = . + KERNEL_VIRT_OFFSET);
+
+    .text.entry : {
+        *(.text.entry)
+    }
+
+    . = ALIGN(16);
+    . = . + KERNEL_VIRT_OFFSET;
+
+    .text : AT(. - KERNEL_VIRT_OFFSET) {
+        KEEP(*(.text.vectors));
+        *(.text*)
+    }
+
+    . = ALIGN(4K);
+    .rodata : AT(. - KERNEL_VIRT_OFFSET) {
+        *(.rodata*)
+        *(.eh_frame*)
+
+        . = ALIGN(16);
+        PROVIDE(__init_array_start = .);
+        KEEP(*(.init_array*))
+        PROVIDE(__init_array_end = .);
+    }
+
+    . = ALIGN(4K);
+    .data.tables : AT (. - KERNEL_VIRT_OFFSET) {
+        KEEP(*(.data.tables))
+    }
+
+    . = ALIGN(4K);
+    .data : AT(. - KERNEL_VIRT_OFFSET) {
+        *(.data*)
+        . = ALIGN(8);
+        PROVIDE(__global_pointer = . + 0x800 - KERNEL_VIRT_OFFSET);
+        *(.got*)
+    }
+
+    . = ALIGN(4K);
+    PROVIDE(__bss_start_phys = . - KERNEL_VIRT_OFFSET);
+    .bss : AT(. - KERNEL_VIRT_OFFSET) {
+        *(COMMON)
+        *(.bss*)
+    }
+    . = ALIGN(4K);
+    PROVIDE(__bss_end_phys = . - KERNEL_VIRT_OFFSET);
+    PROVIDE(__bss_size = __bss_end_phys - __bss_start_phys);
+
+    PROVIDE(__kernel_end = .);
+};
@@ -0,0 +1,25 @@
+{
+  "arch": "riscv64",
+  "os": "none",
+  "abi": "softfloat",
+  "cpu": "generic-rv64",
+  "llvm-target": "riscv64",
+  "data-layout": "e-m:e-p:64:64-i64:64-i128:128-n32:64-S128",
+  "max-atomic-width": 64,
+  "target-pointer-width": "64",
+  "features": "+m,+a,+c",
+
+  "disable-redzone": true,
+  "executables": true,
+  "panic-strategy": "abort",
+  "dynamic-linking": true,
+  "relocation-model": "pic",
+  "eh-frame-header": false,
+
+  "crt-objects-fallback": "false",
+  "emit-debug-gdb-scripts": false,
+  "llvm-abiname": "lp64",
+
+  "linker": "rust-lld",
+  "linker-flavor": "ld.lld"
+}