ENTRY(__x86_64_entry);

KERNEL_PHYS_BASE = 0x200000;
KERNEL_VIRT_OFFSET = 0xFFFFFF8000000000;

SECTIONS {
    . = KERNEL_PHYS_BASE;
    PROVIDE(__kernel_start = . + KERNEL_VIRT_OFFSET);

    .text.entry : {
        *(.text.entry)
    }

    . = ALIGN(16);
    . = . + KERNEL_VIRT_OFFSET;

    .text : AT(. - KERNEL_VIRT_OFFSET) {
        *(.text*)
    }

    .export.text : AT(. - KERNEL_VIRT_OFFSET) {
        KEEP(*(.export.text*))
    }

    . = ALIGN(4K);
    .rodata : AT(. - KERNEL_VIRT_OFFSET) {
        *(.eh_frame*)
        *(.rodata*)
    }

    . = ALIGN(4K);
    .data.tables : AT (. - KERNEL_VIRT_OFFSET) {
        KEEP(*(.data.tables))
    }

    .data : AT(. - KERNEL_VIRT_OFFSET) {
        KEEP(*(.data.yboot))
        *(.data*)
        *(.got*)
    }

    . = ALIGN(4K);
    PROVIDE(__bss_start_phys = . - KERNEL_VIRT_OFFSET);
    .bss : AT(. - KERNEL_VIRT_OFFSET) {
        *(COMMON)
        *(.bss*)
    }
    . = ALIGN(4K);
    PROVIDE(__bss_end_phys = . - KERNEL_VIRT_OFFSET);

    PROVIDE(__kernel_end = .);
};